// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2020-12-08 10:58:01 by jstolfi

#version 3.6;

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca1 = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca2 = 
  texture{
    pigment{ color rgb < 1.00, 0.10, 0.80 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRI��O DA CENA 

#declare raio = 2.500;

// Partes da cena:
  
#declare bolinha = 
  sphere{ < 0,0,0 >, 0.25 texture{ tx_fosca2 } }

#declare caixinha = 
  box{ <-0.5,-0.5,5>, <0.5,0.5,6> texture{ tx_fosca2 } }
 
#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  }
  
#declare pino1 = 
  cylinder{
    < -2.00, +2.00, +1.00 >,
    < +2.00, -2.00, +1.00 >,
    0.2
    texture{ tx_fosca1 }
  }

#declare pino2 = 
  cylinder{
    < 0.00, 0.00, +1.00 >,
    < +2.00, -2.00, +1.00 >,
    0.2
    texture{ tx_fosca1 }
  }

#declare cone1 = 
  cone{
    < 0, 0, +1.00 >,
    1.5,
    < 0, 0, +5.00 >,
    0.25
    texture{ tx_fosca1 }
  }

#declare cone2 = 
  cone{
    < 0, 0, +1.00 >,
    0.25,
    < 0, 0, +5.00 >,
    1.5
    texture{ tx_fosca1 }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

#include "eixos.inc"

// Aqui est� a cena, finalmente:

union{
  //object{ eixos(5.00) }

  object{ chao  translate < 0,0,-5 > texture{ tx_xadrez } }

  object{ caixinha translate < 0,0,+0.5 > }
  object{ cone1 translate < 0,0,+0.5 > }

  object{ bolinha translate < +2.5,-2.5,+2 > }
  object{ pino1  translate < +0.5,-0.5,+1 > }

  object{ bola  translate < 0,0,+2 > }

  object{ bolinha translate < -2.5,+2.5,+2 > }
  object{ pino2  translate < -2.5,+2.5,+1 > }

  object{ caixinha translate < 0,0,-7.5 > }
  object{ cone2 translate < 0,0,-2.5 > }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 2.00 >;
#declare raio_cena = 9.0;
#declare dir_camera = < 7.00, 14.00, 5.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)