// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2017-05-07 20:10:09 by stolfilocal

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.20, 0.62, 0.30 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 0.45;

// Partes da cena:
 
#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  }
  
#declare pino = 
  cylinder{
    <0, 1, 1>,
    <0, 2, 1>,
    0.2
    texture{ tx_fosca }
  }

#declare caixa =
  box {
    <1, -1, 0>,
    <-1, 1, 2>
    texture { tx_xadrez }
  }

#declare filamento =
  cone {
    <0, 1, 1>, 0.0
    <0, 2, 1>, 0.5
    texture { tx_plastico }
  }


#include "eixos.inc"

// Aqui está a cena, finalmente:

union{
  object{ eixos(4.00) }

  object{ caixa texture{ tx_xadrez } }
  object{ filamento  texture{ tx_plastico } }
  object{ filamento  rotate <0,0,180> texture{ tx_plastico } }
  object{ bola  translate < 0,0, 2.45 > texture{ tx_espelho } }
  object{ bola  translate < 0,0,-0.45 > texture{ tx_espelho }  } 
  object{ pino  rotate <0,0, 90> texture{ tx_fosca } }
  object{ pino  rotate <0,0,-90> texture{ tx_fosca } }

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 6.0;
#declare dir_camera = < -10.00, -7.00, 4.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)