// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2017-05-07 20:10:09 by stolfilocal

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_blocked = 
  texture{
    pigment{ color rgb < 1, 0.2, 0.02 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.20, 0.62, 0.30 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 0.3;

// Partes da cena:
 
#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  }


#include "rand.inc"

//Definicao do quadrado fixo de largura l = 5 e profundidade p = 5
#declare l = 20;
#declare p = 20;

//Definicao dos parametros iniciais
#declare N_Pacientes = 10;
#declare Tx_Cont = 2;
#declare minimo = 2; //Dias
#declare maximo = 6; //Dias
#declare Tempo = 25; //Dias

#declare gerador = seed(1224);

//Macro que gera a arvore de infectados de um paciente inicial
#macro arvore(P,S,A,B,T)
    #if (T > 0)
        union{
            object { bola translate <P.x,P.y,P.z> }
            #local SS = S/(S+1);
            #while(rand(gerador) < SS)
                #local altura = RRand(A,B,gerador);
                #if ( (T-altura) > 0 )
                    #local P2 = <P.x + (l/15)*rand(gerador),P.y+(p/15)*rand(gerador),P.z+altura>;
                    cylinder { P, P2, 0.05 texture { tx_fosca } }
                    arvore(P2,S,A,B,T-altura)
                #end
            #end    
        }
    #end    
#end

//Macro que gera o diagrama compostos pelas arvores de infectados de N pacientes iniciais
#macro diagrama(N,S,A,B,T)

    #local i = 0;

    #while (i < N)
        #local P_ini = <l*rand(gerador),p*rand(gerador),0>;

        union{

            object{ arvore(P_ini,Tx_Cont,minimo,maximo,Tempo) }

        }
        #local i = i+1;

    #end
#end


#include "eixos.inc"

// Aqui está a cena, finalmente:


diagrama(N_Pacientes,Tx_Cont,minimo,maximo,Tempo)


#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.00 >;
#declare raio_cena = 23.0;
#declare dir_camera = < 14.00, 10.00, 12.00 >;
#declare dist_camera = 6*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)