// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2020-12-08 11:05:35 by jstolfi

#version 3.6;

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 0.80, 0.80, 0.80 > }
    finish{ diffuse 0.9  ambient 0.1 }
  }

#declare tx_vermelho = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_verde = texture {
  pigment{ color rgb < 0.00, 1.00, 0.00 > }
  finish{ diffuse 0.9  ambient 0.1 }
  
}

// Defines


// ======================================================================
// Macros

#macro garra()
  union {
    object{box {
      <-0.5, -0.05, -0.5>, <0.5, 0.05, 0.5> // <x, y, z> near lower left corner, <x, y, z> far upper right corner
      
    }}
  }

#end

#macro mao(M1,M2)

  union {
    object{box {<-0.7, -0.1, -0.7>, <0.7, 0.1, 0.7> }}

    object{ garra() translate<0, 0, 0.5> rotate <-M1,0,0> translate <0, 0, 0.7>  }

    object{ garra() translate<0, 0, -0.5> rotate <M2,0,0> translate <0, 0, -0.7>  }
  }

#end

#macro antebraco(AR,AL,AF,M1,M2)

  union {
    object{cylinder {<-2, 0, 0>, <2, 0,0 >, 0.2 }}

    object{mao(M1,M2) translate<0.7,0,0> rotate<AR,AL,AF> translate <2, 0, 0> }
  }
#end

#macro braco(B,AR,AL,AF,M1,M2)

  union {
    object{cylinder {<-2, 0, 0>, <2, 0,0 >, 0.2 }}

    object{antebraco(AR,AL,AF,M1,M2) translate <2, 0, 0> rotate <0, 0, B> translate <2, 0, 0>  }
  }

#end

#macro corpo(BR,BL,BF,B,AR,AL,AF,M1,M2,EBR,EBL,EBF,EB,EAR,EAL,EAF,EM1,EM2)

  union {
    object{box {<-1, -1, -3>, <1, 1, 3>} }
    object{sphere {<0, 0, 0>, 1} translate <0, 0, 4>}

    object{braco(B,AR,AL,AF,M1,M2) translate <2, 0, 0> rotate<BR,BL,BF>  translate <1, 0, 1> }

    object{braco(EB,EAR,EAL,EAF,EM1,EM2) translate <2, 0, 0> rotate<EBR,EBL,EBF> scale <-1.0, 1.0, 1.0>  translate <-1, 0, 1> }
    texture{ tx_fosca}
  }

#end


// ======================================================================

#include "eixos.inc"

#local sep = 9*<-1,+1,00>; //Espacamento entre robos.

union{
  // object{ eixos(3.00) }
 
  object{ corpo(-45,0,+30, 100,0,0,0,90,90,   +60,-20,0, 090,0,0,0,30,40) translate -sep }
  object{ corpo(+45,0,+30, 020,0,0,0,90,45,   000,000,0, 100,0,0,0,45,90) }
  object{ corpo(+45,0,+60, 090,0,0,0,90,90,   -40,+30,0, 025,0,0,0,45,90) translate +sep }

}

#include "camlight.inc" 
#declare centro_cena = < -3.00, +3.00, 0.00 >;
#declare raio_cena = 20.0;
#declare dir_camera = < 4.00, 18.00, 4.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)