// Fabio de Souza Azevedo - RA 952215
// 13/ago/2021

// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2020-09-30 19:57:13 by jstolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_vermelho =
  texture {
    pigment { color rgb <0.7, 0.2, 0.1> }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;
#declare h_tronco = 3.0*raio;
#declare l_pino = 1.5*raio;
#declare l_braco = 0.75*h_tronco;
#declare l_perna = 1.1*h_tronco;

// Partes da cena:
  
#declare bolinha = 
  sphere{ < 0,0,0 >, 0.60 }
 
#declare bolota = 
  sphere{ < 0,0,0 >, 1.50 }
 
#declare bola =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  }
  
#declare pino = 
  cylinder{
    //< -2.00, +2.00, -1.00 >,
    //< +2.00, -2.00, +1.00 >,
    < -l_pino, 0.00, 0.00 >,
    < +l_pino, 0.00, 0.00 >,
    0.75
    texture{ tx_fosca }
  }
  
#declare furo = 
  cylinder{
    < -1.00, -2.00, -2.00 >,
    < +1.00, +2.00, +2.00 >,
    0.75*raio
    texture{ tx_fosca }
  }

#declare chao = 
  box{ <-20,-20,-1>, <+20,+20,0> }

// Novas partes da cena:

#declare tronco =
  union {
    object { bola }
    cylinder {
      <0.0, 0.0, 0.0>,
      <0.0, 0.0, h_tronco>
      0.75*raio
      texture { tx_fosca }
    }
    object { bola translate <0.0, 0.0, h_tronco> }
  }

#declare braco =
  union {
    object { bolota scale 0.75 }
    cylinder {
      <0.0, 0.0, 0.0>,
      <0.0, 0.0, -l_braco>,
      0.65
    }
  }

#declare perna =
  union {
    object { bolota scale 0.75 }
    cylinder {
      <0.0, 0.0, 0.0>,
      <0.0, 0.0, -l_perna>,
      0.65
    }
  }


#include "eixos.inc"

// Aqui está a cena, finalmente:

union {
  object { eixos(5.00) }

  object { chao translate < 0,0,-8 > texture { tx_xadrez } }

  union {
    object { tronco }

    object { pino }
    object { pino translate <0.0, 0.0, h_tronco> }
    object { braco
      rotate <-25,0,0>
      translate <+l_pino, 0.0, h_tronco> texture { tx_espelho }
    }
    object { braco
      rotate <+25,0,0>
      translate <-l_pino, 0.0, h_tronco> texture { tx_espelho }
    }
    object { perna
      rotate <+25,0,0>
      translate <+l_pino, 0.0, 0.0> texture { tx_espelho }
    }
    object { perna
      rotate <-25,0,0>
      translate <-l_pino, 0.0, 0.0> texture { tx_espelho }
    }

    object { bolota
      translate <0.0, 0.0, h_tronco+1.3*raio> texture { tx_espelho }
    }

    object {
      bolinha translate <-0.3*raio, 0.5*raio, h_tronco+1.3*raio>
      texture { tx_vidro } interior { ior 1.01 }
    }
    object {
      bolinha translate <+0.3*raio, 0.5*raio, h_tronco+1.3*raio>
      texture { tx_vidro } interior { ior 1.01 }
    }
    rotate <-15,0,0>
    translate <4.0, 4.0, 0.0>
  }
}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 0.00 >;
#declare raio_cena = 16.0;
#declare dir_camera = < 14.00, 3*7.00, 4.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)