// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2021-12-08 23:41:10 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico_verde = 
  texture{
    pigment{ color rgb < 0.10, 1.00, 0.70 > }
    finish{ diffuse 1.0 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca_amarela = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_vidro_verde = 
  texture{
    pigment{ color rgb < 0.00, 1.00, 0.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_fosca_vermelha = 
texture{
  pigment{ color rgb <1.00, 0.20, 0.20> }
  finish{ diffuse 0.9 ambient 0.1 }
}

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.15, 0.20, 0.65 >, color rgb < 0.80, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRI��O DA CENA 

#declare raio_grande = 2.00;
#declare raio_pequeno = raio_grande*0.5;
#declare altura = 8.00;
#declare extensao_do_chao = 40.00;

// Partes da cena:
  
#declare bola_central = 
  sphere{ < 0,0,0 >, raio_grande }
 
#declare bolinha = 
  sphere{ < 0,0,0 >, raio_pequeno }
 
#declare disco =
  cylinder{
    < 0.00, 0.00, 0.5 >, < 0.00, 0.00, -0.50 >, raio_grande*3.00 
  }


#declare caixinha = 
  box{
    < 0.75, 0.75, 0.75>, <-0.75, -0.75, -0.75>
  }


#declare furo = 
  cylinder{
    < 0.00, 0.00, -2.00 >,
    < 0.00, 0.00, +2.00 >,
    0.60*raio_pequeno
  }

#declare raio_trator = 
  cone{
    <0.00, 0.00, 0.00>, 0.00, <0.00, 0.00, -altura>, raio_grande*1.50
  }

#declare chapeu = 
  cone{
    <0.00, 0.00, 0.00>, 0.00, <0.00, 0.00, 1.00>, raio_pequeno*1.50
  }

#declare chao = 
  box{ <-extensao_do_chao,-extensao_do_chao,-1>, <+extensao_do_chao,+extensao_do_chao,0> }

// Aqui est� a cena, finalmente:

union{

  object{ chao translate <0.00, 0.00, -altura> texture{ tx_xadrez } }
  object{ bola_central texture{ tx_fosca_amarela } }

  difference{
    union{
      object{ disco texture{ tx_plastico_verde } }
      object{ bolinha translate < +4,0.00,0.00 > texture{ tx_fosca_amarela } }
      object{ bolinha translate < -4,0.00,0.00 > texture{ tx_fosca_amarela } }
      object{ bolinha translate < 0,+4,0.00 > texture{ tx_fosca_amarela } }
      object{ bolinha translate < 0,-4,0.00 > texture{ tx_fosca_amarela } }
    }
    object{ furo translate < +4.00, 0.00, 0.00 > texture{ tx_fosca_amarela } }
    object{ furo translate < -4.00, 0.00, 0.00 > texture{ tx_fosca_amarela } }
    object{ furo translate < 0.00, +4.00, 0.00 > texture{ tx_fosca_amarela } }
    object{ furo translate < 0.00, -4.00, 0.00 > texture{ tx_fosca_amarela } }
  }
  
  object{ raio_trator texture{ tx_vidro_verde }}

  object{ caixinha translate <0, 0, raio_grande> texture{ tx_fosca_vermelha }}
  object{ chapeu translate <0.00, 0.00, raio_grande+0.50> texture{ tx_plastico_verde }}

}

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, -1.00 >;
#declare raio_cena = 12.0;
#declare dir_camera = < 14.00, 7.00, 6.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)