// Fabio de Souza Azevedo - RA 952215
// 2021-08-25
//
// TP02

// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2021-12-09 07:39:13 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }


#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:

// ----- Nave Alienigena
#macro nave_alien()
  union {
    sphere { <0.0, 0.0, 0.0>, 0.75 texture { tx_fosca } }
    cone { <+4.0, 0.0, 0.0>, 0, <+0.0, +0.0, 0.0>, 0.5 texture { tx_plastico } }
    cylinder { <0.0, 0.0, 0.0>, <-2.0, 0.0, 0.0>, 0.3 texture { tx_fosca } }
  }
#end

// ----- Nave Terraquea
#macro nave_terra()
  #local lc = 2.0;    // largura da caixa
  #local ac = 1.0*lc; // altura da caixa
  union {
    box { <-lc/2.0, -lc/2.0, 0.0>, <+lc/2.0, +lc/2.0, ac>
      texture { tx_fosca }
    }
    cylinder { <0.0, 0.0, ac>, <0.0, 0.0, ac+1.5>, 0.3 texture { tx_plastico } }
    sphere { <0.0, 0.0, ac+1.5>, 0.75 texture { tx_fosca } }
  }
#end

#macro grade_alien(lins, cols)
  union {
    #local l = 0;
    #while (l < lins)
      #local c = 0;
      #while (c < cols)
        #if (sin(15*c*l) > 0.7)
          object { nave_alien() translate <6*l, 2*(c-cols/2), 0.0> }
        #end
        #local c = c+1;
      #end
      #local l = l+1;
    #end
  }
#end

#macro grade_terra(lins, cols)
  union {
    #local l = 0;
    #while (l < lins)
      #local c = 0;
      #while (c < cols)
        #if (sin(15*c*l) > 0.7)
          object { nave_terra() translate <3*l, 3*(c-cols/2), 0.0> }
        #end
        #local c = c+1;
      #end
      #local l = l+1;
    #end
  }
#end




#include "eixos.inc"

// Aqui está a cena, finalmente:

#declare lins_aliens = 15;
#declare cols_aliens = 10;

#declare lins_terra = 8;
#declare cols_terra = 12;

//object { eixos(8.0) }

object { grade_alien(lins_aliens, cols_aliens) }
object { grade_terra(lins_terra, cols_terra) translate <-4*lins_terra, 0, 0> }

#include "camlight.inc"
//#declare centro_cena = <2*lins_aliens, 1.2*cols_aliens, 1.00>; 
#declare centro_cena = < (6*lins_aliens - 2*lins_terra)/2, 0.00, 1.00 >;
// #declare raio_cena = 3.0*sqrt(lins_terra*lins_terra + cols_terra*cols_terra); 
#declare raio_cena = 40.0;
#declare dir_camera = < 14.00, 7.00, 4.00 >;
#declare dist_camera = 5*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)