// Fabio de Souza Azevedo - RA 952215
// 2021-10-06
//
// TP07 - Animação do robô alienigenoide

// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2021-12-12 04:58:33 by stolfi

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.85, 0.30 > }
    finish{ diffuse 0.2 reflection 0.7*< 1.00, 0.85, 0.30 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.85, 0.95, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare tx_verde_escuro =
  texture{
    pigment { color rgb <0, 0.5, 0> }
    //finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_verde_claro =
  texture{
    pigment { color rgb <0, 1.0, 0> }
    //finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_azul_escuro = 
  texture{
    pigment { color rgb<0, 0, 0.5> }
    //finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }
  
#declare tx_azul_escuro_espelhado = 
  texture{
    pigment { color rgb<0, 0, 0.5> }
    finish{ diffuse 0.2 reflection 0.7*<0, 0, 0.5> ambient 0.1 }
  }

#declare tx_verm_escuro = 
  texture{
    pigment { color rgb<0.5, 0, 0> }
    //finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_verm_transp = 
  texture{
    pigment { color rgbt <1, 0, 0, 0.5> }
    //finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_xadrez =
  texture{
    pigment{ checker color rgb < 0.10, 0.32, 0.60 >, color rgb < 1.00, 0.97, 0.90 > }
    finish{ diffuse 0.9 ambient 0.1 }
    scale 2.0
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

// Pernas

#declare w_pe = 0.25; // referência para a largura do pé

#macro pe()
  #local uu = 1.0;
  box { <+0.0, -uu, 0.0>, <+4.0*uu, +uu, +uu> }
#end

#macro pe_tornozelo(ang_pe)
  #local rr = 0.25;
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    object {
      pe()
      scale rr*<1,1,1> translate <0, 0, -rr> rotate <0, +ang_pe, 0>
      texture { tx_verde_claro }
    }
  }
#end

#macro canela(ang_pe)
  #local rr = 0.25;
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    cylinder { 0, <0.0, 0.0, -8.0*rr>, 0.7*rr texture { tx_verde_claro } }
    object { pe_tornozelo(ang_pe) translate <0.0, 0.0, -8.0*rr> }
  }
#end

#macro perna(ang_joelho, ang_pe)
  #local rr = 0.25;
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    cylinder { 0, <0.0, 0.0, -10.0*rr>, 0.7*rr texture { tx_verde_claro } }
    object {
      canela(ang_pe)
      rotate <0, ang_joelho, 0>
      translate <0.0, 0.0, -10.0*rr>
    }
  }
#end

#macro quadril(ang_femur_dir, ang_joelho_dir, ang_pe_dir,
               ang_femur_esq, ang_joelho_esq, ang_pe_esq)
  #local alt = 1.5;
  #local rr = 1.0;
  union {
    cylinder { 0, <0, 0, alt>, rr texture { tx_verm_transp } }
    // perna direita
    object {
      perna(ang_joelho_dir, ang_pe_dir)
      rotate <0, ang_femur_dir, 0>
      translate <0, -rr, 0>
    }
    // perna esquerda
    object {
      perna(ang_joelho_esq, ang_pe_esq)
      rotate <0, ang_femur_esq, 0>
      translate <0, +rr, 0>
    }
  }
#end

// Braços

#declare w_garra = 0.75*w_pe;
#macro old_garra()
  box {
    <+0.0, -w_garra, 0.0>, <+4*w_garra, +w_garra, +w_garra>
    texture { tx_verde_claro }
  }  
#end
#macro garra()
  #local uu = 1.0;
  box { <0.0, -uu, 0.0>, <+uu, +uu, -4.0*uu> }  
#end

#macro mao(ang_ga, ang_gp)
  // {ang_ga} = Ângulo da garra anterior (< 0)
  // {ang_gp} = Ângulo da garra posterior (> 0)
  #local rr = 0.25;
  #local s = 0.75; // {s} = um fator de escala apenas
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    // garra anterior
    object {
      garra()
      scale s*rr*<1,1,1>      
      translate <0,0,0> rotate <0, ang_ga, 0>
      texture { tx_verde_claro }
    }
    // garra posterior
    object {
      garra()
      scale s*rr*<1,1,1>
      translate <-s*rr,0,0> rotate <0, ang_gp, 0>
      texture { tx_verde_escuro }
    }
  }
#end

#macro antebraco(ang_mao, ang_ga, ang_gp)
  // {ang_mao} = Giro da mao em relação ao eixo do antebraço
  // {ang_ga} = Ângulo da garra anterior (< 0)
  // {ang_gp} = Ângulo da garra posterior (> 0)
  #local rr = 0.25;
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    cylinder { 0, <0.0, 0.0, -6.0*rr>, 0.7*rr texture { tx_verde_claro } }
    object {
      mao(ang_ga, ang_gp)
      rotate <0, 0, ang_mao>
      translate <0.0, 0.0, -6.0*rr>
    }
  }
#end

#macro braco(ang_cotovelo, ang_mao, ang_ga, ang_gp)
  #local rr = 0.25;
  union {
    sphere { 0, rr texture { tx_verde_escuro } }
    cylinder { 0, <0.0, 0.0, -6*rr>, 0.7*rr texture { tx_verde_claro } }
    object {
      antebraco(ang_mao, ang_ga, ang_gp)
      rotate <0, ang_cotovelo, 0>
      translate <0.0, 0.0, -6*rr>
    }
  }
#end

#macro ombro(ang_ombro_dir, ang_cotovelo_dir, ang_mao_dir, ang_ga_dir, ang_gp_dir,
             ang_ombro_esq, ang_cotovelo_esq, ang_mao_esq, ang_ga_esq, ang_gp_esq)
  #local alt = 1.5;
  #local r = 1.0;
  union {
    cylinder { 0, <0, 0, alt>, r texture { tx_verm_transp } }
    // braço direito
    object {
      braco(ang_cotovelo_dir, ang_mao_dir, ang_ga_dir, ang_gp_dir)
      rotate <0, ang_ombro_dir, 0>
      translate <0, -r, alt>
    }
    // braço esquerdo
    object {
      braco(ang_cotovelo_esq, ang_mao_esq, ang_ga_esq, ang_gp_esq)
      rotate <0, ang_ombro_esq, 0>
      translate <0, +r, alt>
    }
  }
#end

#macro cabeca()
  #local alt = 1.5;
  #local r_base = 0.25;
  #local r_topo = 4*r_base;
  union {
    cylinder { 0, <0, 0, 0.5>, r_base texture { tx_verde_escuro } }
    cone { <0, 0, 0.5>, r_base, <0, 0, 0.5+alt>, r_topo texture { tx_verde_claro } }
  }
#end

#macro robo(ang_ombro_dir, ang_cotovelo_dir, ang_mao_dir, ang_ga_dir, ang_gp_dir,
            ang_ombro_esq, ang_cotovelo_esq, ang_mao_esq, ang_ga_esq, ang_gp_esq,
            ang_femur_dir, ang_joelho_dir, ang_pe_dir,
            ang_femur_esq, ang_joelho_esq, ang_pe_esq)
  #local alt = 1.5;
  #local r = 1.0;
  union {
    object { quadril(ang_femur_dir, ang_joelho_dir, ang_pe_dir,
                     ang_femur_esq, ang_joelho_esq, ang_pe_esq) }
    object {
      ombro(ang_ombro_dir, ang_cotovelo_dir, ang_mao_dir, ang_ga_dir, ang_gp_dir,
            ang_ombro_esq, ang_cotovelo_esq, ang_mao_esq, ang_ga_esq, ang_gp_esq)
      translate <0,0,+alt>
    }
    object { cabeca() translate <0,0,2*alt> }
  }
#end

#macro interpola1(tt, tt0,tt1, vv0,vv1)
  #local rr = (tt - tt0)/(tt1 - tt0);
  #local vv = (1-rr)*vv0 + rr*vv1;
  vv
#end

#macro quadro(tf)
  #local T0 = 0.00;
  //#local P0 = ...
  #local P0_ang_ombro_dir = 0;
  #local P0_ang_ombro_esq = 0;
  #local P0_ang_femur_dir = 0;
  #local P0_ang_femur_esq = 0;

  #local T1 = 0.25;
  //#local P1 = ...
  #local P1_ang_ombro_dir = -90;
  #local P1_ang_ombro_esq = +90;
  #local P1_ang_femur_dir = -45;
  #local P1_ang_femur_esq = +45;

  #local T2 = 0.50;
  //#local P2 = ...
  #local P2_ang_ombro_dir = -180;
  #local P2_ang_ombro_esq = +180;
  #local P2_ang_femur_dir = 0;
  #local P2_ang_femur_esq = 0;

  #local T3 = 0.80;
  //#local P3 = ...
  #local P3_ang_ombro_dir = -270;
  #local P3_ang_ombro_esq = +270;
  #local P3_ang_femur_dir = +45;
  #local P3_ang_femur_esq = -45;

  #local T4 = 1.00;
  //#local P4 = P0
  #local P4_ang_ombro_dir = P0_ang_ombro_dir;
  #local P4_ang_ombro_esq = P0_ang_ombro_esq;
  #local P4_ang_femur_dir = P0_ang_femur_dir;
  #local P4_ang_femur_esq = P0_ang_femur_esq;


  #if ((T0 <= tf) & (tf <= T1))
    #local tt = (tf - T0)/(T1 - T0);
    //#local qd = robo interpola(tt, P0, P1);
    #local ang_ombro_dir = interpola1(tt, T0,T1, P0_ang_ombro_dir, P1_ang_ombro_dir);
    #local ang_ombro_esq = interpola1(tt, T0,T1, P0_ang_ombro_esq, P1_ang_ombro_esq);
    #local ang_femur_dir = interpola1(tt, T0,T1, P0_ang_femur_dir, P1_ang_femur_dir);
    #local ang_femur_esq = interpola1(tt, T0,T1, P0_ang_femur_esq, P1_ang_femur_esq);

  #elseif ((T1 <= tf) & (tf <= T2))
    #local tt = (tf - T1)/(T2 - T1);
    //#local qd = robo interpola(tt, P1, P2);
    #local ang_ombro_dir = interpola1(tt, T1,T2, P1_ang_ombro_dir, P2_ang_ombro_dir);
    #local ang_ombro_esq = interpola1(tt, T1,T2, P1_ang_ombro_esq, P2_ang_ombro_esq);
    #local ang_femur_dir = interpola1(tt, T1,T2, P1_ang_femur_dir, P2_ang_femur_dir);
    #local ang_femur_esq = interpola1(tt, T1,T2, P1_ang_femur_esq, P2_ang_femur_esq);

  #elseif ((T2 <= tf) & (tf <= T3))
    #local tt = (tf - T2)/(T3 - T2);
    //#local qd = robo interpola(tt, P2, P3);
    #local ang_ombro_dir = interpola1(tt, T2,T3, P2_ang_ombro_dir, P3_ang_ombro_dir);
    #local ang_ombro_esq = interpola1(tt, T2,T3, P2_ang_ombro_esq, P3_ang_ombro_esq);
    #local ang_femur_dir = interpola1(tt, T2,T3, P2_ang_femur_dir, P3_ang_femur_dir);
    #local ang_femur_esq = interpola1(tt, T2,T3, P2_ang_femur_esq, P3_ang_femur_esq);

  #elseif ((T3 <= tf) & (tf <= T4))
    #local tt = (tf - T3)/(T4 - T3);
    //#local qd = robo interpola(tt, P3, P4);
    #local ang_ombro_dir = interpola1(tt, T3,T4, P3_ang_ombro_dir, P4_ang_ombro_dir);
    #local ang_ombro_esq = interpola1(tt, T3,T4, P3_ang_ombro_esq, P4_ang_ombro_esq);
    #local ang_femur_dir = interpola1(tt, T3,T4, P3_ang_femur_dir, P4_ang_femur_dir);
    #local ang_femur_esq = interpola1(tt, T3,T4, P3_ang_femur_esq, P4_ang_femur_esq);
  #end
  //qd
  robo(ang_ombro_dir,0,0,+15,-15, ang_ombro_esq,0,0,+45,-45, // ombro
       ang_femur_dir,0,0, ang_femur_esq,0,0) // quadril
#end

#include "eixos.inc"

// Aqui está a cena, finalmente:

//object { eixos(8.0) }

object { quadro(clock) }

/* REFERENCIA:
robo(ang_ombro_dir, ang_cotovelo_dir, ang_mao_dir, ang_ga_dir, ang_gp_dir,
     ang_ombro_esq, ang_cotovelo_esq, ang_mao_esq, ang_ga_esq, ang_gp_esq,
     ang_femur_dir, ang_joelho_dir, ang_pe_dir,
     ang_femur_esq, ang_joelho_esq, ang_pe_esq)
*/

#include "camlight.inc"
#declare centro_cena = < 0.00, 0.00, 1.50 >;
#declare raio_cena = 12.0;
#declare dir_camera = < 7.00, 14.00, 4.00 >;// < 7.00, 3.00, 4.00 >;
#declare dist_camera = 4*raio_cena;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)