// Last edited on 2023-12-28 15:41:18 by stolfi

// Raio da grade debug:
// #declare rdb = 0.1;
#declare rdb = 0;

background{ color rgb < 0.95, 0.85, 0.90 > }

#include "retalho.inc"

#macro poltrona()
  #local r1 = array[4][4];
  #local r2 = array[4][4];
  #local r3 = array[4][4];

  #local r1[0][0] = < 50,  0, 20 >;
  #local r1[1][0] = < 50,  2, 20 >;
  #local r1[2][0] = < 50, 15, 15 >;
  #local r1[3][0] = < 50, 20,  0 >;
  #local r1[0][1] = < 40,  0, 30 >;
  #local r1[1][1] = < 40,  2, 30  >;
  #local r1[2][1] = < 40, 15, 25 >;
  #local r1[3][1] = < 40, 20, 10 >;
  #local r1[0][2] = < 30,  0, 30 >;
  #local r1[1][2] = < 30,  2, 30 >;
  #local r1[2][2] = < 30, 15, 25 >;
  #local r1[3][2] = < 30, 20, 10 >;
  #local r1[0][3] = < 20,  0, 25 >;
  #local r1[1][3] = < 20,  2, 25 >;
  #local r1[2][3] = < 20, 15, 20 >;
  #local r1[3][3] = < 20, 20,  5 >;

  #local r2[0][0] = r1[3][0];               // < 50, 20,  0 >
  #local r2[1][0] = 2*r2[0][0] - r1[2][0];  // < 50, 25, -15 >
  #local r2[2][0] = < 50, 38, -20 >;
  #local r2[3][0] = < 50, 40, -20 >;
  #local r2[0][1] = r1[3][1];
  #local r2[1][1] = 2*r2[0][1] - r1[2][1];
  #local r2[2][1] = < 40, 38, -10 >;
  #local r2[3][1] = < 40, 40, -10 >;
  #local r2[0][2] = r1[3][2];
  #local r2[1][2] = 2*r2[0][2] - r1[2][2];
  #local r2[2][2] = < 30, 38, -10 >;
  #local r2[3][2] = < 30, 40, -10 >;
  #local r2[0][3] = r1[3][3];
  #local r2[1][3] = 2*r2[0][3] - r1[2][3];
  #local r2[2][3] = < 20, 38, -15 >;
  #local r2[3][3] = < 20, 40, -15 >;

  union{
    object { retalho(r1, rdb, cret0, 3) }
    object { retalho(r2, rdb, cret1, 3) }
  }
#end

#declare cmin = < +18.0,  -2.0, -24.0 >;
#declare cmax = < +52.0, +42.0, +34.0 >;

object{ poltrona() }

#include "eixos.inc"
#if (rdb > 0) object{ eixos(20.0) } #end

#include "gaiola.inc"
#if (rdb > 0) object{ gaiola(cmin,cmax) } #end
#if (rdb = 0) object{ gaipiso(cmin,cmax) } #end

#declare centro_cena = (cmin + cmax)/2;
#declare raio_cena = 0.65*vlength(cmax-cmin);
#declare dist_camera = 7*raio_cena;

#include "camlight.inc"
#declare dir_camera = < 7, 5, 3 >;
#declare intens_luz = 1.20;
camlight(centro_cena, raio_cena, dir_camera, dist_camera , z, intens_luz)