// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2009-03-09 18:44:03 by stolfi

// ======================================================================
// CÂMERA 

camera{
  location  1.2*< 14.00, 7.00, 3.50 >  // Posição do observador.
  right     -0.45*x                // Largura RELATIVA da imagem.
  up        0.60*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 1.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source{
  10 * < +50.0, +30.0, +50.0 >           // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source{
  10 * < +50.0, -10.0, +10.0 >           // Posição da lâmpada.
  color rgb 0.5 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// EIXOS DE COORDENADAS

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{ 
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.6, 0.6, 0.6 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 reflection 0.1*< 0.6, 0.6, 0.6 > }
  }
#declare tx_plastico_transparente = 
  texture{
    pigment{ color rgb < 0.8, 0.8, 0.8 > filter 0.70 }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }
#declare tx_fruta = 
  texture{
    pigment{ color rgb < 1, 0, 0 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 0.92,0.8,0.51 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_corte = 
  texture{
    pigment{ color rgb < 1.00,0.80,0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.90, 0.70 > }
    finish{ diffuse 0.1 reflection 0.8*< 1.00, 0.90, 0.70 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

// Partes da cena:

#declare corpo = 
   cylinder { < 0,0,0 >, < 0,0,2.3 >, 1.50 }

#declare corpo_topo = 
   cylinder { < 0,0,0 >, < 0,0,1 >, 1.50 }

#declare corpo_burraco = 
   cylinder { < 0,0,0 >, < 0,0,3.1 >, 1.30 }

#declare corpo_topo_boca = 
   cylinder { < 0,0,0 >, < 0,0,1 >, 0.50 }

#declare corpo_topo_boca_burraco = 
   cylinder { < 0,0,0 >, < 0,0,1.2 >, 0.40 }

#declare corpo_funil =
   cylinder { < 0,0,0 >, < 0,0,1 >, 0.30 }

#declare corpo_funil_burraco =
   cylinder { < 0,0,0 >, < 0,0,1.1 >, 0.15 }

#declare corpo_manivela_ombro =
   cylinder { < 0,0,0 >, < 0,0,0.3 >, 0.20 }

#declare corpo_manivela_braco =
   box { < 0,0,0 >, < 0.4,0.50,1.5 > }

#declare corpo_manivela_mao =
   cylinder { < 0,0,0 >, < 0,0,1 >, 0.20 }

#declare fruta = 
  sphere{ < 0,0,0 >, 0.30 }

#declare corte =
   box { < 0,0,0 >, < 6,3,6 > }

// Aqui está a cena, finalmente:
#declare cena =
   union{
      // INICIO CORPO
      difference {
         // DIFERENÇA PARA DAR O EFEITO DA FINURA DO PLASTICO DO CORPO e O 'VAZIO' DENTRO DO OBJETO
         union {
            object{ corpo translate < 0,0,-2 > texture{ tx_plastico } }
            object{ corpo_topo translate < 0,0,0.3 > texture{ tx_plastico_transparente } }
            object{ corpo_topo_boca translate < 0,0,1.3 > texture{ tx_plastico_transparente } }
            object{ corpo_funil rotate 135*y translate < 1.2,0,0 > texture{ tx_plastico_transparente } }
            object{ corpo_manivela_ombro rotate -90*x translate < 0,1.5,0 > texture{ tx_fosca } }
	    object{ corpo_manivela_braco translate < -0.2,1.8,-1.3 > texture{ tx_fosca } }
            object{ corpo_manivela_mao rotate -90*x translate < 0,2.3,-1.1 > texture{ tx_fosca } }
         }
         union {
            object{ corpo_burraco translate < 0,0,-1.9 > texture{ tx_plastico_transparente } }
            object{ corpo_topo_boca_burraco translate < 0,0,1.2 > texture{ tx_plastico_transparente } }
            object{ corpo_funil_burraco rotate 135*y translate < 1.2,0,0 > texture{ tx_plastico_transparente } }
         }
      }
   
      // FIM CORPO
   
      // INICIO FRUTAS (coloquei umas frutas dentro do objeto para mostrar o burraco dentro dele
      object{ fruta translate < 0,0,2 > texture{ tx_fruta } }
      object{ fruta translate < 0,-0.2,0 > texture{ tx_fruta } }
      // FIM FRUTAS
   }

union {
   object { cena translate < 0,-3,0 > }
   intersection {
      object { cena translate < 0,3,0 > }
      object { corte translate < -3,0,-3 > texture{ tx_corte } }
   }
   rotate -10*z
}