// Last edited on 2009-08-26 13:04:06 by stolfilocal
// Processed by remove-cam-lights

#declare distS = 0.7;

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.20, 0.85, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_plastico2 =
  texture{
    pigment{ color rgb < 0.10, 0.80, 0.80 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 0.90, 0.90, 0.90 > }
    finish{ diffuse 0.1 reflection 1.0 ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare corte =
  texture{
    pigment{ color rgb < 0.97, 0.00, 0.00 >}
    finish{ diffuse 0.0 ambient 1.0 specular 0.0 roughness 0.005 }
  }

#declare entrada =
difference{
 cylinder{<0, 0, 0>, <0, 0, 0.3>, 0.5 texture {tx_plastico}}
 cylinder{<0, 0, 0>, <0, 0, 0.4>, 0.45 texture {tx_plastico}}
}

#declare manivela =
union{
 cylinder{<0, 1, -1>, <0, 1.2, -1>, 0.1 texture {tx_plastico}}
 sphere {<0, 1.2, -1>, 0.12 texture {tx_plastico}}
 cylinder {<0, 1.2, -1>, <0, 1.2, -2>, 0.1 texture {tx_plastico}}
 sphere {<0, 1.2, -2>, 0.12 texture {tx_plastico}}
 cylinder {<0, 1.2, -2>, <0, 1.7, -2>, 0.1 texture {tx_plastico}}
 sphere {<0, 1.7, -2>, 0.12 texture {tx_plastico}}
}

#declare saida =
difference{
 cylinder{<0.5, 0, -2>, <1.5, 0, -2.5>, 0.15 texture {tx_plastico}}
 union{
  cylinder{<0.5, 0, -2>, <1.5, 0, -2.5>, 0.1 texture {tx_plastico}}
  box {<1.6, -1, -3>, <1.4, 1, -2> texture {tx_plastico}}
 }
}

#declare juicer =
union{
 object {entrada}
 object {manivela}
 object {saida translate <0,0, 1>}
 box
 {
  <-1, -1, -2.7>, <1, 1, 0> texture {tx_plastico2}
 }
}

#declare copo =
difference {
 cylinder{<0,0,0>, <0,0,1>, 0.3 texture {tx_vidro}}
 cylinder{<0,0,0.05>, <0,0,1.1>, 0.25 texture {tx_vidro}}
}

#declare cortador =
union{
 box{<1, -1, -3>, <-1, 0, 2>}
 box{<-1, 1, -3>, <0, -1, 2>}
}

intersection
{
 object {juicer}
 object {cortador scale <2, 2, 2> translate <0, 0, 3> texture {corte}}
 translate <0, 0, -1>
}

object {juicer translate <0, 0, 3>}

// Original camera parameters:
// #local cam_ctr = <0,0,0>
// #local cam_vec = (<14.00,10.00,5.50>*distS)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0,0,0>,0.5*10.0,<10,10,7>,10.0,z,1.2)