// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2009-03-09 18:44:03 by stolfi

// ======================================================================
// CÂMERA 

camera{
  location  < 24.00, 17.00, 17.00 >  // Posição do observador.
  right     -0.45*x                // Largura RELATIVA da imagem.
  up        0.60*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 0.00, 1.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source{
  10 * < +50.0, +30.0, +50.0 >           // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source{
  10 * < +50.0, -10.0, +10.0 >           // Posição da lâmpada.
  color rgb 0.5 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// EIXOS DE COORDENADAS

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{ 
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.90, 0.70 > }
    finish{ diffuse 0.1 reflection 0.8*< 1.00, 0.90, 0.70 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 

#declare raio = 2.000;

// Partes da cena:
 
#declare bolota = 
  sphere{ < +1.00, -1.5, +1.00 >, 0.10 
  texture{ tx_fosca }
  }
 
#declare bola_grande =
  sphere{
    < 0.00, 0.00, 0.00 >, raio 
    texture{ tx_plastico }
  } 
  
#declare base = 
	cylinder{
    < +0.00, +0.00, +0.00 >,
    < +0.00, +0.00, +3.00 >,
    0.55*raio
    texture{ tx_fosca }
  }

#declare bocal_1 = 
	cylinder{
    < +0.00, +0.00, +0.00 >,
    < +0.00, +0.00, +4.00 >,
    0.20*raio
    texture{ tx_fosca }
  }
  
#declare bocal_2 = 
	cylinder{
    < +0.00, +0.00, +0.00 >,
    < +0.00, +0.00, +5.00 >,
    0.10*raio
    texture{ tx_fosca }
  }

#declare manivela_base = 
	cylinder{
    < +0.00, +0.00, +0.00 >,
    < +1.00, -1.5, +0.00 >,
    0.05*raio
    texture{ tx_fosca }
  }
  
#declare manivela_pino = 
	cylinder{
	< +1.00, -1.5, +0.00 >,
	< +1.00, -1.5, +1.00 >,
    0.05*raio
    texture{ tx_fosca }
  }

#declare manivela = 
	cylinder{
	< +1.00, -1.5, +1.00 >,
	< +1.40, -2.5, +0.99 >,
    0.05*raio
    texture{ tx_fosca }
  }
  
#declare escorredor_1 = 
	box{
	< +0.00, +0.00, +0.00 >,
	< +3.0, 1.00, +1.0 >
    texture{ tx_fosca }
  }	
  
#declare escorredor_2 = 
	box{
	< -1.00, +0.00, +0.00 >,
	< +4.00, +0.5, +0.5 >
    texture{ tx_fosca }
  }	

#declare caixa = 
    box{
 	 < 10,5,5 >,
	 < 0,0,0 > 
  }
  
#declare cena = 
 union
  {
	  object{ base  }
	  difference{
	   		object{ bocal_1 }
	  		object{ bocal_2 }
	  } 
	  object{ manivela_base translate < 0,0,+2 > }
	  object{ manivela_pino translate < 0,0,+2 > }
	  object{ manivela translate <0,0,+2> }
	  object{ bolota translate <0,0,+2> }
	  difference{
		  object{ escorredor_1 translate <0,-0.2,0.5> }
		  object{ escorredor_2 translate <0,-0.2,0.5> }  
	  }
  } 
// Aqui está a cena, finalmente:

union{
  object{ eixos(3.00) }
  intersection{
	  object {cena translate <5,0,0>}
	  object {caixa }
  }
  object {cena translate <-5,0,0>}
 
  rotate 70*z
   
}