// Last edited on 2009-10-10 19:46:01 by stolfilocal
// Processed by remove-cam-lights

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_parede =
  texture{
    pigment{ color rgb < 0.9, 0.9, 0.9 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.90, 0.70 > }
    finish{ diffuse 0.1 reflection 0.8*< 1.00, 0.90, 0.70 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#declare raio = 2.000;

#macro corpo(p1,p2,p3,p4,p5,p6,p7,p8,p9,p10,p11,p12,p13,p14,p15,p16,p17,p18,c1,c2,a1,a2,a3,a4)
union
{
        sphere{ <0,0,0>, 1 texture{tx_fosca} scale <2,1,1> }
        object{ perna(p1,p2,p3) translate <-1,.8,-.5> }
        object{ perna(p4,p5,p6) scale <1,-1,1> translate <-1,-.8,-.5>  }

        object{ perna(p7,p8,p9) translate <0,.8,-.5> }
        object{ perna(p10,p11,p12) scale <1,-1,1> translate <0,-.8,-.5>  }

        object{ perna(p13,p14,p15) translate <1,.8,-.5> }
        object{ perna(p16,p17,p18) scale <1,-1,1> translate <1,-.8,-.5>  }

        object{ pescoco_e_cabeca(c1,c2) translate <1.9,0,.4> }

        object{ asa(a1,a2) translate <0,0,0> }
        object{ asa(a3,a4) scale <1,-1,1> }
}

#end

#macro pescoco_e_cabeca(alfa,beta)
union
{
        sphere{ <0,0,0>, .2 texture{tx_fosca} }
        cylinder{ <0,0,0>, <0,0,1.5> .1 texture{tx_fosca} }
        sphere{ <0,0,0>, .2 texture{tx_fosca} translate <0,0,1.5> }
        cone{ <0,0,0>, .1, <.2,0,0>, 0 texture{tx_fosca} translate <.13,0,1.5> rotate beta*y }
        rotate alfa*y
}
#end

#macro perna(alfa,beta,gama)
union
{
        sphere{ <0,0,0> .2 texture{tx_fosca} }
        cylinder{ <0,0,0>,<0,0,-1> .1  texture{tx_espelho} }
        object{ joelho_canela_pe(beta,gama) translate <0,0,-1> }
        rotate alfa*y
}
#end

#macro joelho_canela_pe(alfa, beta)
union
{
        sphere{ <0,0,0>, .2 texture{tx_fosca} }
        cylinder{ <0,0,0>,<0,0,-1> .1 texture{tx_espelho} }
        union
        {
                sphere{ <0,0,0>, .2 texture{tx_fosca} translate <0,0,-1> }
                box{ <0,0,0>, <.8,.6,.3> rotate -beta*y translate <-.25,-.3,-1.4> texture{tx_espelho} }

        }
        rotate alfa*y
}
#end

#macro asa(alfa, beta)
union
{
        sphere{ <0,0,0>, .2 texture{tx_fosca} }
        cylinder{ <0,0,0>, <0,0,1.5> .1 texture{tx_fosca} }
        sphere{ <0,0,0>, .2 texture{tx_fosca} translate <0,0,1.5> }
        cone{ <0,0,0>, .14, <1,0,0>, 0 texture{tx_fosca} rotate beta*y translate <0,0,1.5>}
        scale <-1,1,1>

        rotate alfa*y
        translate <.5,.8,.6>
}
#end

union
{

    object{ 
      corpo
        ( 50,-30,-20,
          50,-30,-20,
          50,-60,-20,
          50,-45,-20,
          50,-45,-30,
          50,-60,-30,
          40,1,
          -30,30,-55,15
        ) 
      translate <-4,+4,0>
    }
    object{ 
      corpo
        ( 40,-40,-20,
          40,-40,-20,
          40,-40,-20,
          50,-45,-20,
          50,-45,-30,
          50,-60,-30,
          30,1,
          -20,10,-30,25
        )
      translate <0,0,0>
    }
    object{ 
      corpo
        ( 60,-45,-20,
          60,-55,-20,
          60,-40,-20,
          50,-45,-20,
          50,-45,-30,
          50,-60,-30,
          50,1,
          -10,20,-40,40
        )
      translate <+4,-4,0>
    }
}

// Original camera parameters:
// #local cam_ctr = <0,0,0>
// #local cam_vec = <14.00,7.00,3.50>
// #local cam_sky = z

#include "camlight.inc"
camlight(<+0.2,-0.2,-0.2>,8.0,<10,10,3>,30.0,z,1.2)