// Last edited on 2009-10-10 19:48:42 by stolfilocal
// Processed by remove-cam-lights

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_fosca_laranja =
  texture{
    pigment{ color rgb < 1.00, 0.50, 0.00 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_fosca_branca =
  texture{
    pigment{ color rgb < 1.00, 1.00, 1.00 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }


#macro pe()
        box{< 0, -1.5, 0 >, < 0.5,1.5, 4 > }
#end

#macro canela_pe(beta)
        union{
                cylinder{ < 0, 0, 0 >, < 8, 0, 0>, 1 }
                sphere{< 0, 0, 0 >, 0.95 }
                sphere{< 0, 0, 0 >, 0.95 translate <8,0,0>}
                object{pe()
                        rotate beta*y
                        translate 8*x
                }
                texture{ tx_fosca_branca}
        }

#end

#macro coxa(alfa, beta)
        union{
                cone{ < 0, 0, 0 >, 3, < 10, 0, 0>, 1 texture{ tx_fosca}}
                sphere{< 0, 0, 0 >, 2.95 texture{ tx_fosca}}
                object{canela_pe(beta)
                        rotate alfa*y
                        translate 10*x
                }
        }

#end

#macro coxa_posicao(gama, alfa, beta, posicao)
        object{
                        coxa(alfa, beta)
                        rotate gama*y
                        rotate 90*y
                        rotate -90*z
                        translate 7*x
                        translate posicao*y
                }
#end

#macro cabeca()
        union{
                sphere{< 0, 0, 0 >, 2 }
                cone{< 1.9, 0, 0 >, 0.5,< 3.2, 0, 0 >, 0
                        texture{ tx_fosca_laranja}
                }
                rotate 60*y
                translate 2*x
        }
#end

 #macro pescoco(delta)
        union{
                cylinder{ < 0, 0, 0 >, < 5, 0, 0>, 0.8  }
                sphere{< 5, 0, 0 >, 0.75 }
                object{
                        cabeca()
                        rotate delta*y
                        translate 4*x
                }
                texture{ tx_fosca_branca}
                scale 1.8
        }
#end

#macro asa_ponta()
        union{
                cylinder{ < 0, 0, 0 >, < 8, 0, 0>, 1  }
                sphere{< 0, 0, 0 >, 0.95 }
                sphere{< 0, 0, 0 >, 0.95 translate <8,0,0>}

        }

#end

#macro asa(epsilon)
        union{
                cylinder{ < 0, 0, 0 >, < 8, 0, 0>, 1}
                sphere{< 0, 0, 0 >, 0.95 }
                object{asa_ponta()
                        rotate epsilon*y
                        translate 8*x
                }

                texture{ tx_fosca}

        }

#end

#macro galinha(gamaE1, gamaE2, gamaE3, gamaD1,gamaD2,gamaD3,
        alfaE1, alfaE2, alfaE3, alfaD1, alfaD2, alfaD3,
        betaE1, betaE2, betaE3, betaD1, betaD2, betaD3,
        teta, delta, epsilon)

        union{
                sphere{ < 0, 0, 0 >, 12 texture{ tx_fosca}
                scale <0.8,1.3,0.8>}

                object{coxa_posicao(gamaE1, alfaE1, betaE1, -7)}
                object{coxa_posicao(gamaE2, alfaE2, betaE2, 0)}
                object{coxa_posicao(gamaE3, alfaE3, betaE3, 7)}

                object{coxa_posicao(gamaD1, alfaD1, betaD1, -7) scale <-1,1,1>}
                object{coxa_posicao(gamaD2, alfaD2, betaD2, 0)scale <-1,1,1>}
                object{coxa_posicao(gamaD3, alfaD3, betaD3, 7)scale <-1,1,1>}

                object{
                        pescoco(delta)
                        rotate teta*y
                        rotate -80*y
                        rotate -90*z

                        translate -11*y
                        translate 6*z
                }

                object {asa(epsilon)
                        rotate -45*y
                        rotate 60*x
                        translate 7*x
                        translate 5*z
                }
                object {asa(epsilon)
                        rotate -45*y
                        rotate 60*x
                        translate 7*x
                        translate 5*z
                        scale <-1,1,1>
                }

        }

#end


#declare raio = 2.000;

 union{
        // object{ eixos(3.00) }

        union{

                object {galinha(
                        10,45,70,40,45,50,
                        -60, -40,-50,-50,-40,-60,
                        30, 10,20,30,20,30,
                        60, 60,160)
                        rotate 70*z
                        translate <0,0,0>}

                object {galinha(
                        10,20,30,10,20,30,
                        -45,-40,-35,-45,-40,-35,
                        20,30,40,50,20,30,
                        45, 10,90)
                        rotate 70*z
                        translate <-30,+30,0>}

                object {galinha(
                        0,10,60,30,40,60,
                        -30,-10,0,-30,-20,-10,
                         0, 10,20,10,0,20,
                        10, -20,30)
                        rotate 70*z
                        translate <+30,-30,0>}

                // scale 0.15
                // rotate 30*z

        }

 }

// Original camera parameters:
// #local cam_ctr = <0.00,0.00,1.00>
// #local cam_vec = (<14.00,7.00,7.00>-<0.00,0.00,1.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,0.00,0.00>,58.0,<10,10,4>,165.0,z,1.2)