// Last edited on 2009-10-10 20:06:26 by stolfilocal
// Processed by remove-cam-lights

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico =
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca =
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_fosca_preta =
  texture{
    pigment{ color rgb < 0.00, 0.00, 0.00 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_fosca_branca =
  texture{
    pigment{ color rgb < 1.00, 1.00, 1.00 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_fosca2 =
  texture{
    pigment{ color rgb < 1.00, 0.10, 0.10 > }
    finish{ diffuse 0.7 ambient 0.3 }
  }

#declare tx_espelho =
  texture{
    pigment{ color rgb < 1.00, 0.90, 0.70 > }
    finish{ diffuse 0.1 reflection 0.8*< 1.00, 0.90, 0.70 > ambient 0.1 }
  }

#declare tx_vidro =
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

#macro pe()
        box {
                < -1.5, 0.00,  -1.00 >,
                <  1.5, 1.00,   3.00 >
                texture{ tx_fosca }
        }
#end

#macro canela_com_pe(beta)
        union {
                cylinder{ <0,0,0>, <0,10,0>, 1
                        texture{ tx_fosca }
                }
                sphere{
                        < 0, 10, 0>, 1
                        texture{ tx_fosca }
                }
                object{ pe()
                        rotate -beta*x
                        translate 10*y
                }
        }
#end

#macro perna(alfa, beta)
        union {
                cylinder{ <0,0,0>, <0, 7, 0>, 1
                        texture{ tx_fosca }
                }
                sphere{
                        < 0, 7, 0>, 1
                        texture{ tx_fosca }
                }
                object{ canela_com_pe(beta)
                        rotate alfa * x
                        translate <0, 7, 0>
                }
        }
#end

#macro cabeca()
        union {

                sphere{
                        < 0, 0, 0>, 4
                        texture{ tx_fosca2 }
                }

                sphere{
                        < 3.3, 0, 0>, 1
                        texture{ tx_fosca_preta }
                }
                sphere{
                        < -3.3, 0, 0>, 1
                        texture{ tx_fosca_preta }
                }

                cone { <0,3,0>, 2.0, <0,8,0>, 0
                        texture{ tx_fosca }
                }
        }
#end

#macro pescoco_cabeca(g_cabeca)
        union {
                cylinder{ <0,0,0>, <0, 9, 0>, 1
                        texture{ tx_fosca }
                }
                sphere{
                        < 0, 9, 0>, 1
                        texture{ tx_fosca }
                }
                object{ cabeca()
                        rotate 90*x
                        rotate g_cabeca*x
                        translate <0,9,0>}
        }
#end

#macro asinha()
        union {

                cone { <0,0,0>, 2.0, <0,5,0>, 1.5
                        texture{ tx_fosca }
                }
        }
#end

#macro asa(g_asinha)
        union {
                cylinder{ <0,0,0>, <0,6,0>, 2
                        texture{ tx_fosca }
                }
                sphere { <0.0, 6.0, 0.0 >, 2
                        texture{ tx_fosca }
                }
                object{ asinha()
                        rotate g_asinha*x
                        translate <0.0, 6.0, 0.0 >
                }
        }
#end

#macro galinha(p_esq1_teta, p_esq1_alfa, p_esq1_beta, p_dir1_teta, p_dir1_alfa, p_dir1_beta, p_esq2_teta, p_esq2_alfa, p_esq2_beta, p_dir2_teta, p_dir2_alfa, p_dir2_beta, p_esq3_teta, p_esq3_alfa, p_esq3_beta, p_dir3_teta, p_dir3_alfa, p_dir3_beta, g_cabeca, g_pescoco, g_asinha, g_asa)
        union {

                sphere { <0.0, 0.0, 0.0 >, 1
                        scale <8, 15, 8>
                        texture{ tx_fosca2 }
                }
                cone { <0,15,0>, 1.0, <0,17,0>, 3
                        texture{ tx_fosca }
                }

                sphere { <2.0, -6.0, -7.0 >, 1
                        texture{ tx_fosca }
                }
                object{ perna(p_esq1_alfa, p_esq1_beta)
                        rotate 180*y
                        rotate -p_esq1_teta*x
                        translate <2, -6, -7.0>
                }

                sphere { <-2.0, -6.0, -7.0 >, 1
                        texture{ tx_fosca }
                }
                object{ perna(p_dir1_alfa, p_dir1_beta)
                        rotate 180*y
                        rotate -p_dir1_teta*x
                        translate <-2, -6, -7.0>
                }

                object{ perna(p_esq2_alfa, p_esq2_beta)
                        rotate 180*y
                        rotate -p_esq2_teta*x
                        translate <2, 0, -7.5>
                }
                sphere { <2.0, 0.0, -7.5 >, 1
                        texture{ tx_fosca }
                }

                object{ perna(p_dir2_alfa, p_dir2_beta)
                        rotate 180*y
                        rotate -p_dir2_teta*x
                        translate <-2, 2, -7.5>
                }
                sphere { <-2.0, 2.0, -7.5 >, 1
                        texture{ tx_fosca }
                }

                object{ perna(p_esq3_alfa, p_esq3_beta)
                        rotate 180*y
                        rotate -p_esq3_teta*x
                        translate <2, 6, -7.0>
                }
                sphere { <2.0, 6.0, -7.0 >, 1
                        texture{ tx_fosca }
                }

                object{ perna(p_dir3_alfa, p_dir3_beta)
                        rotate 180*y
                        rotate -p_dir3_teta*x
                        translate <-2, 6, -7.0>
                }
                sphere { <-2.0, 6.0, -7.0 >, 1
                        texture{ tx_fosca }
                }

                object{ pescoco_cabeca(g_cabeca)
                        rotate 90*x
                        rotate g_pescoco*x
                        translate <0, -10, 6>
                }
                sphere { <-0, -10, 6 >, 1
                        texture{ tx_fosca }
                }

                object{ asa(g_asinha)
                        rotate -90*x
                        rotate -g_asa*y
                        translate <8,0,0>
                }
                sphere { <8, 0, 0 >, 2
                        texture{ tx_fosca }
                }

                object{ asa(g_asinha)
                        rotate -90*x
                        rotate g_asa*y
                        translate <-8,0,0>
                }
                sphere { <-8, 0, 0 >, 2
                        texture{ tx_fosca }
                }

        }
#end

union {

  object{ 
    galinha
      ( 45, 90, 45,  
        45, 90, 45,  
        45, 90, 45,  
        45, 90, 45,  
        45, 90, 45,  
        45, 90, 45,  
        00, 45,  
        90, 45 
      )
    rotate 65*z
  }

  object{ 
    galinha
      ( 45, 90, 60,  
        60, 90, 45,  
        45, 90, 60,  
        60, 90, 45,  
        45, 90, 60,  
        60, 90, 45,  
        00, 70,  
        60, 60 
      )
    rotate 65*z
    translate <-33,+33,0>
  }

  object{ 
    galinha
      (  90,  60,  00,  
         75,  90,  00,  
         45,  90,  45,  
         45,  90,  45,  
         15,  90,  10,  
         35,  90, -20,  
         40,  45,  
         60, 125
      )
    rotate 65*z
    translate <+33,-33,0>
  }
}

// Original camera parameters:
// #local cam_ctr = <0.00,20.00,0.00>
// #local cam_vec = (<200.00,0.00,0.0>-<0.00,20.00,0.00>)
// #local cam_sky = z

#include "camlight.inc"
camlight(<0.00,00.00,0.00>,65.0,<10,10,3>,230.0,z,1.2)