// Exemplo de arquivo de descricao de cena para POV-ray
// Last edited on 2009-03-09 18:44:03 by stolfi

// ======================================================================
// CÂMERA 


camera{
  location  < 35.0, 15.00, 5.0 >  // Posição do observador.
  right     -0.45*x                // Largura RELATIVA da imagem.
  up        0.60*y                 // Altura RELATIVA da imagem.      
  sky       z                      // Qual direção é "para cima"?
  look_at   <  0.00, 2.00, 0.00 >  // Para onde a câmera está apontando.
} 
// Nota: os parâmetros "right" e "up" devem ter a mesma proporção
// que os parâmetros ${WIDTH} e ${HEIGHT} no Makefile.

// ======================================================================
// FONTES DE LUZ

light_source{
  10 * < +50.0, +30.0, +50.0 >           // Posição da lâmpada.
  color rgb 1.0 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

light_source{
  10 * < +50.0, -10.0, +10.0 >           // Posição da lâmpada.
  color rgb 0.5 * < 1.00, 1.00, 1.00 >   // Intensidade e corda luz.
} 

// ======================================================================
// EIXOS DE COORDENADAS

#macro eixo(ponta,cor,nome)
  union{
    sphere{ <0,0,0>, 0.02 }
    cylinder{ <0,0,0>, 0.91*ponta, 0.02 }
    cone{ 0.90*ponta, 0.06, ponta, 0.00 }
    texture{ pigment{ color rgb cor } finish{ ambient 0.5 diffuse 0.5 } }
  }
#end
#macro eixos(tamanho)
  union{ 
    object{ eixo( <tamanho,0,0>, <1.0,0.2,0.2>, "X") }
    object{ eixo( <0,tamanho,0>, <0.0,0.8,0.0>, "Y") }
    object{ eixo( <0,0,tamanho>, <0.3,0.3,1.0>, "Z") }
  }
#end

// ======================================================================
// CORES E TEXTURAS

background{ color rgb < 0.75, 0.80, 0.85 > }

#declare tx_plastico = 
  texture{
    pigment{ color rgb < 0.10, 0.80, 1.00 > }
    finish{ diffuse 0.8 ambient 0.1 specular 0.5 roughness 0.005 }
  }

#declare tx_fosca = 
  texture{
    pigment{ color rgb < 1.00, 0.80, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_preta = 
  texture{
    pigment{ color rgb < 0.00, 0.00, 0.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_branca = 
  texture{
    pigment{ color rgb < 1.00, 1.00, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }
 
#declare tx_fosca_vermelha = 
  texture{
    pigment{ color rgb < 1.00, 0.00, 0.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }

#declare tx_fosca_azul = 
  texture{
    pigment{ color rgb < 0.00, 0.00, 1.00 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }
#declare tx_fosca2 = 
  texture{
    pigment{ color rgb < 1.00, 0.10, 0.10 > }
    finish{ diffuse 0.9 ambient 0.1 }
  }


#declare tx_espelho = 
  texture{
    pigment{ color rgb < 1.00, 0.90, 0.70 > }
    finish{ diffuse 0.1 reflection 0.8*< 1.00, 0.90, 0.70 > ambient 0.1 }
  }

#declare tx_vidro = 
  texture{
    pigment{ color rgb < 0.97, 0.98, 1.00 > filter 0.70 }
    finish{ diffuse 0.03 reflection 0.25 ambient 0.02 specular 0.25 roughness 0.005 }
  }

// ======================================================================
// DESCRIÇÃO DA CENA 


#macro coluna_lathe()
	#local p1 = <1,0>;
	#local p2 = <2,2>;
	#local p3 = <2,4>;
	#local p6 = <1,8>;
	#local p4 = (p3 + p6)/2;
	#local p5 = p4;
	#local p7 = <1,10>;
	#local p10 = <2,14>;
	#local p8 = (p7 + p10)/2;
	#local p9 = p8;
	#local p11 = <2,16>;
	#local p12 = <1,18>;

	lathe { bezier_spline
			12
			p1, p2, p3, p4, p5, p6, p7, p8, p9, p10, p11, p12 
			texture{ tx_fosca }
	}
#end


#macro coluna_prism_linear()
	#local p1 = <2,0>;
	#local p2 = <3,2>;
	#local p3 = <1,3>;
	#local p6 = <-1,3>;
	#local p4 = (p3 + p6)/2;
	#local p5 = p4;
	#local p7 = <-2, 0>;
	#local p10 = <0,-2>;
	#local p8 = (p7 + p10)/2;
	#local p9 = p8;
	#local p11 = <-1,3>;
	#local p12 = <2,0>;

	prism { linear_sweep
			bezier_spline
			0,
			18,
			12
			p1, p2, p3, p4, p5, p6, p7, p8, p9, p10, p11, p12 
			texture{ tx_fosca }
	}
#end



#macro coluna_prism_conic()
	#local p1 = <2,0>;
	#local p2 = <3,2>;
	#local p3 = <1,3>;
	#local p6 = <-1,3>;
	#local p4 = (p3 + p6)/2;
	#local p5 = p4;
	#local p7 = <-2, 0>;
	#local p10 = <0,-2>;
	#local p8 = (p7 + p10)/2;
	#local p9 = p8;
	#local p11 = <-1,3>;
	#local p12 = <2,0>;


	#local p1 = <0.2,0>;
	#local p2 = <0.3,0.2>;
	#local p3 = <0.1,0.3>;
	#local p6 = <-0.1,0.3>;
	#local p4 = (p3 + p6)/2;
	#local p5 = p4;
	#local p7 = <-0.2, 0>;
	#local p10 = <0,-0.2>;
	#local p8 = (p7 + p10)/2;
	#local p9 = p8;
	#local p11 = <-0.1,0.3>;
	#local p12 = <0.2,0>;

	prism { conic_sweep
			bezier_spline
			1,
			4.6,
			12
			p1, p2, p3, p4, p5, p6, p7, p8, p9, p10, p11, p12 
			texture{ tx_fosca }
	}
#end




// declaração da cena

union {
	eixos(4)

	//piso
	box {
		<0.0, 0.0, 0.0>
		<10, 10, -0.1>
		texture{ tx_fosca_azul }
	}
	box {
		<0.0, 0.0, -0.1>
		<11, 10, -0.2>
		texture{ tx_fosca_azul }
	}	
	box {
		<0.0, 0.0, -0.2>
		<12, 10, -0.3>
		texture{ tx_fosca_azul }
	}	

	

	//teto
	prism {
		linear_sweep
		0,
		10
		4
		<0,0>, <10,0>, <5,2>, <0,0>
		texture{ tx_fosca_vermelha }
		rotate z*90
		translate <10,0,3.6>
	}


	object{ coluna_lathe() 
			scale 0.2
			rotate 90*x 
			translate <8, 2, 0>}
	
	object{ coluna_lathe() 
			scale 0.2
			rotate 90*x 
			translate <8, 8, 0>}
	
	object { coluna_prism_linear() 
			scale 0.2 
			rotate 90*x
			translate <2,5,0>
			rotate -45*z			
			}
	object { coluna_prism_conic() 
			translate z-1
			rotate 90*x
			translate <5, 9, 0>
			}


}