#! /bin/csh -fe
# Last edited on 2003-11-20 22:58:50 by stolfi

echo "=== begin $0 =========" 

set cmd = "$0"
set usage = "${cmd:t} RUN INBAND INTAG OUTBAND OUTTAG"

if ( $#argv != 5 ) then
  echo "usage: ${usage}"; exit 1
endif

set run = "$1"; shift;
set inBand = "$1"; shift;
set inTag = "$1"; shift
set outBand = "$1"; shift;
set outTag = "$1"; shift

if ( "x${inBand}" != "x${outBand}" ) then

  echo "inBand = ${inBand} inTag = ${inTag}"
  echo "outBand = ${outBand} outTag = ${outTag}" 

  source RUN-${run}/f${outBand}.parms

  @ extraLength = ( ( 6 * ${outBand} ) + 9 ) / 10
  echo "extraLength = ${extraLength}"

  set outStep = "${step}"
  echo "outStep = ${outStep}"

  set blurFactor = 3.0
  echo "blurFactor = ${blurFactor}"

  set maxMergeShift = `gawk -v h=${outBand} 'BEGIN{printf "%.2f", 1.0*h;}'`
  echo "maxMergeShift = ${maxMergeShift}"

  set minMergeOverlap = `gawk -v h=${outBand} -v b=${blurFactor} 'BEGIN{printf "%.2f", (1.0+b)*h;}'`
  echo "minMergeOverlap = ${minMergeOverlap}"
  
  echo "maxDrawCands = ${maxDrawCands}"
  echo "candDrawStep = ${candDrawStep}"

  set input = RUN-${run}/f${inBand}-${inTag}
  set output = RUN-${run}/f${outBand}-${outTag}
  echo "${input} -> ${output}"

  nice -n 19 PZMapCands \
    -input ${input} \
    -inBand ${inBand} \
    -chainDir . -chainPrefix f \
    -output ${output} \
    -outBand ${outBand} \
    -outStep ${outStep} \
    -blurFactor ${blurFactor} \
    -extraLength ${extraLength} \
    -mergeCands ${maxMergeShift} ${minMergeOverlap}

  # nice -n 19  PZDrawCands \
  #  -input ${prefix}-f${outBand}-${outTag} \
  #  -chainPrefix ${prefix} \
  #  -band ${outBand} \
  #  -output ${prefix}-f${outBand}-${outTag} \
  #  -maxCands ${maxDrawCands} \
  #  -plotStep 2.0

else
  echo "mapping to same band, skipped"
endif

echo "=== end $0 ========="