//  UNICAMP name based on Nelson Machado's Postscript logo
//  Last edited on 1999-10-01 14:22:03 by stolfi

//  Assumes declared 
//    logo_uc_name_stemR
//    logo_uc_name_stemHY
//    logo_uc_name_texture

//  Defines
//    logo_uc_name = the name, parallel to the XZ plane, 
//          with approximate X range [-0.70 __ +0.70], baseline at Z = 0

// For design purposes, capitals are 8 units tall

#declare stemR = 1.0 * logo_uc_name_stemR;
#declare stemHY = 1.0 * logo_uc_name_stemHY;
#include "fonts/unicamp-var-0800/ALL.inc"

// The entire logo

#declare sp = 1.000;  // letter spacing

#declare logo_uc_name_tx = object{ glyphUCaseU }
#declare xc = widthUCaseU;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseN translate xc*x }}
#declare xc = xc + widthUCaseN;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseI translate xc*x }}
#declare xc = xc + widthUCaseI;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseC translate xc*x }}
#declare xc = xc + widthUCaseC;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseA translate xc*x }}
#declare xc = xc + widthUCaseA;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseM translate xc*x }}
#declare xc = xc + widthUCaseM;

#declare xc = xc + sp;
#declare logo_uc_name_tx = union{ object{ logo_uc_name_tx } object{ glyphUCaseP translate xc*x }}
#declare xc = xc + widthUCaseP;

#declare logo_uc_name_scale = +1.40 / xc;
#declare logo_uc_name_height = logo_uc_name_scale * heightUCaseM;

#declare logo_uc_name =
  object{ logo_uc_name_tx
    bounded_by{
      box{ 
        < 00-0.01, -1.01*stemHY, -0.01 >,
        < xc+0.01, +1.01*stemHY, +0.01+heightUCaseM >
      }
    }
    scale logo_uc_name_scale
    translate < -0.70, 0, 0 >
    texture{ logo_uc_name_texture }
  }