// Test of the new crackle texture
// Last edited on 2000-08-05 18:25:44 by stolfi

light_source {
  <0.0000, 50.0000, 0.0000>
  color rgb <1.20, 1.20, 1.20>
} 

#declare centerX = 0;
#declare centerY = 0;
#declare centerZ = 0;

#declare camDX = 2.1;
#declare camDY = 6;
#declare camDZ = -2.5;

#declare skyX = 0;
#declare skyY = 1;
#declare skyZ = 0;

camera {
  location  <centerX, centerY, centerZ> + <camDX, camDY, camDZ>
  direction <-camDX, -camDY, -camDZ>
  right     <+3.8000, 00.0000, 00.0000>
  up        <00.0000, 00.0000, +5.3200>
  sky       <skyX, skyY, skyZ>
  look_at   <centerX, centerY, centerZ>
} 

#declare blueColor  = color rgb <0.25, 0.35, 0.50>;
#declare pinkColor  = color rgb <1.00, 0.85, 0.70>;
#declare redColor   = color rgb <1.00, 0.20, 0.00>;
#declare whiteColor = color rgb <1.00, 1.00, 1.00>;
#declare blackColor = color rgb <0.00, 0.00, 0.00>;

#declare metalFinish =
  finish{
    metallic
    ambient 0.1
    diffuse 0.9
    specular 1 roughness 0.05
    brilliance 2
  }

#declare crackleTexture = 
  texture{
    pigment{
      crackle
      color_map{
        [0.000 redColor]
        [0.167 redColor]
        [0.167 whiteColor]
        [0.333 whiteColor]
        [0.333 blueColor]
        [0.500 blueColor]
        [0.500 whiteColor]
        [0.667 whiteColor]
        [0.667 blueColor]
        [0.833 blueColor]
        [0.833 whiteColor]
        [1.000 whiteColor]
      }
      frequency 2
    }
    finish { ambient 0.1 diffuse 0.9 }
  }

#declare plainTexture = 
  texture{
    pigment {color whiteColor}
    finish { ambient 0.3 diffuse 0.7 }
  }

#include "background.inc"

background{ color bgColor }

box {
  <-1.2, 00.0, -1.2>,
  <+1.2, +0.6, +1.2>
  texture{ 
    crackleTexture
    scale 0.5
  }
}

sphere{
  <00.0, +1.1, +1.5>, 0.5
  texture{ crackleTexture }
}