#! /bin/csh -f
# Last modified on Wed Jan 25 04:22:16 1989 by stolfi 
#==================================================
# Usage: spool-ps-file
#   [-P<printer>] [-S<spooler>] [-c<copies>] <postscript file>
# Ships postscript file to spooling machine, and 
#   runs lpr [-P<printer>] -s there.
#==================================================

set printerop = "-P$PRINTER"
set spooler = ""
set copies = ""
while ( $#argv > 1 )
  if ( "X$1" == "X-P" ) then
    set printerop = "-P"$2
    shift; shift
  else if ( "X$1" =~ X-P* ) then
    set printerop = $1
    shift
  else if ( "X$1" == "X-S" ) then
    set spooler = $2
    shift; shift
  else if ( "X$1" =~ X-S* ) then
    set spooler = `echo $1 | sed s/-P//`
    shift
  else if ( "X$1" =~ X-c* ) then
    set copies = $1
    shift
  else
    break
  endif
end

if ( $#argv < 1  ) then
  echo "Missing argument"
  exit(1)
endif

foreach f ( $* )
  set f = $f:r
  if ( ( "X$spooler" == "X" ) || ( "X$spooler" == "X$MACHINE" ) ) then
    nice lpr $printerop -s $f.ps
  else
    echo shipping $f.ps to $spooler... &&\
    copy $f.ps /$spooler/tmp/$$-$f.ps &&\
    msh $spooler "nice lpr $printerop -s /tmp/$$-$f.ps"
  endif
end

# END