//  The central orb, radius 1 
//  Last edited on 1999-02-13 22:13:27 by stolfi

//  Requires
//    sib_core_orb_flatten
//    sib_core_sea_texture
//    sib_core_land_texture
//    sib_core_grid_texture
//    sib_core_dot_texture
//    sib_core_beam_color
//    sib_core_light_color
//  Defines
//    sib_core

#declare orb_land_texture = texture{ sib_core_land_texture }
#declare orb_sea_texture = texture{ sib_core_sea_texture }
#declare orb_grid_texture = texture{ sib_core_grid_texture }
#declare orb_dot_texture = texture{ sib_core_dot_texture }
#declare orb_focus_lon = -45;
#declare orb_focus_lat = -23;
#include "orb.inc"

#declare sib_core =
  union{
    object{ orb
      rotate < 000, 037, 000 >  // rotate globe before squashing
      rotate < 012, 000, 000 >  // rotate globe before squashing
      scale   < -1, +1, sib_core_orb_flatten >
    }    
    
    cylinder { < 00.0, 00.0, -0.3 >, < 00, +20, 00 >, 3.50 
      hollow
      pigment { color rgbt <1,1,1,1> }
      interior {
        media { 
          emission 0.6*sib_core_beam_color
          density{ cylindrical }
        }
      }
      rotate < 090, 000, 000 >
    }
    light_source {
      < 000, 000, 120 > 
      color rgb 0.8*sib_core_light_color
      spotlight
      point_at < 0, 0, 0 >
      radius 3 falloff 6
    } 
    light_source {
      < 00.0, 00.0, +2.0 > 
      color rgb 0.3*sib_core_light_color
    } 
  }