SUBROUTINE DELLNP (QLN, DPDPHI, DPDLAM, EPS)
C      SUBROUTINE COMPUTES SPHERICAL HARMONIC COEFFICIENTS OF
C         COS(LAT) * GRAD(LN(PI))
C      FROM SPHERICAL HARMONIC COEFFICIENTS OF LN(PI)
C      USED IN NONLIN TERMS A AND B
C      WHEN GRAD(LN(PI)) IS NEEDED IN ZLN AND SIGMADOT
C      DIVIDE BY COS(LAT) AFTER EXPANSION ON LAT. CIRCLE,
      DIMENSION QLN( 17 , 17 ), DPDPHI( 18 , 17 ),
     1  DPDLAM( 17 , 17 ), EPS( 18 , 17 )
C      NOTE DIFFERENT TRUNCATION IN GRADIENT COMPONENTS.
      COMPLEX QLN, DPDPHI, DPDLAM
      DOUBLE PRECISION EPS
C      DPDPHI = COS(LAT) D(LN(PI)) / A*D(LAT)
C      DPDLAM =          D(LN(PI)) / A*D(LON) = I*L*Q(L,N)
      DO 2 LL=1, 17
      FL=LL-1
      DO 2 IND=1, 17
C      RI=CMPLX(0.,1.)
C      DPDLAM(IND,LL)=RI*FL*QLN(IND,LL)
      DPDLAM(IND,LL)=CMPLX(-AIMAG(QLN(IND,LL))*FL,REAL(QLN(IND,LL))*FL)
    2 CONTINUE
      DO 4 LL=1, 17
      L=LL-1
      N=L
C      DPDPHI(1,LL)=(L+2.) * EPS(2,LL) * QLN(2,LL)
      DPDPHI(1,LL)=CMPLX(SNGL(REAL(QLN(2,LL))*((L+2.)*EPS(2,LL))),
     1    SNGL(AIMAG(QLN(2,LL))*((L+2.)*EPS(2,LL))))
      DO 3 IND=2, 16
      N=N+1
C      DPDPHI(IND,LL)=(N+2.)*EPS(IND+1,LL)*QLN(IND+1,LL)
C    1   +(1.-N)*EPS(IND,LL)*QLN(IND-1,LL)
      DPDPHI(IND,LL)=CMPLX(SNGL((N+2.)*EPS(IND+1,LL)*
     1   REAL(QLN(IND+1,LL)) + (1.-N)*EPS(IND,LL)*REAL(QLN(IND-1,LL))),
     2   SNGL((N+2.)*EPS(IND+1,LL)*AIMAG(QLN(IND+1,LL)) +
     3   (1.-N)*EPS(IND,LL)*AIMAG(QLN(IND-1,LL))))
    3 CONTINUE
C     N=N+1
C      DPDPHI( 17 ,LL)=-(L+ 16 -1) * EPS( 17 ,LL) * QLN( 16 ,LL)
      DPDPHI( 17 ,LL)=CMPLX(-SNGL((L+ 16 -1)*EPS( 17 ,LL)*
     1    REAL(QLN( 16 ,LL))), -SNGL((L+ 16 -1)*EPS( 17 ,LL)*
     2    AIMAG(QLN( 16 ,LL))))
C     N=N+1
C      DPDPHI( 18 ,LL)=-(L+ 16 )*EPS( 18 ,LL)*QLN( 17 ,LL)
      DPDPHI( 18 ,LL)=CMPLX(-SNGL((L+ 16 )*EPS( 18 ,LL)*
     1 REAL(QLN( 17 ,LL))), -SNGL((L+ 16 )*EPS( 18 ,LL)*
     2 AIMAG(QLN( 17 ,LL))))
    4 CONTINUE
      AA=1./ 6370000.
      DO 5 J=1, 17
      DO 5 I=1, 17
      DPDLAM(I,J)=CMPLX( REAL(DPDLAM(I,J))*AA  ,
     1                  AIMAG(DPDLAM(I,J))*AA  )
    5 CONTINUE
      DO 6 J=1, 17
      DO 6 I=1, 18
      DPDPHI(I,J)=CMPLX( REAL(DPDPHI(I,J))*AA  ,
     1                  AIMAG(DPDPHI(I,J))*AA  )
    6 CONTINUE
C(DEBUGLINE) VERSION CREATED JULY 8 1982 BY J.SELA,NMC.
      RETURN
      END