#! /usr/bin/gawk -f
# Last edited on 2004-01-27 06:50:44 by stolfi

BEGIN{ 
  state = "base";
}

/^ *[\#@]/ { print; next; }
/./ { gsub(/[&][\#]8207[;]/, "", $0); }
/^ *$/ { next; }

# Decide state of next non-tag text:
/<H1 ALIGN="CENTER">/ { state = "header"; next; }
/<[\/]H1>/ { state = "base"; next; }

/<A NAME=["]([0-9]*)_([0-9]*)["]>/ { 
  print gensub(/<A NAME=["]0*([0-9]*)_0*([0-9]*)["]>/, "  @verse{\\1}{\\2}", "g", $0);
  state = "verse";
  next;
}

/<FONT[^<>]*COLOR=GREEN>/ { state = "vnum"; next; }
/<[\/]FONT>/ { state = ((state == "vnum") || (state == "verse") ? "verse" : "base") ; next; }

/<P ALIGN="RIGHT">/ { print "@="; next; }
/<[\/]P>/ { print "@="; next; }

/^[<]/ { next; }

(state == "header") { 
  print gensub(/^ *([0-9]+)[.] *(.*)$/, "@chapter{\\1}{sura}{\\2}", "g", $0);
  state = "base"; 
  next;
}

(state == "vnum") {
  print gensub(/^ *0*([0-9]+)[:]0*([0-9]+)$/, "  @verse{\\1}{\\2}", "g", $0);
  state = "verse";
  next; 
}

(state == "verse") { 
  printf "  %s\n", $0; 
  next; 
}

(state == "base") { 
  printf "ignored: %s\n", $0 > "/dev/stderr"; 
  next; 
}